Скрипт очистки каталога (папки) от файлов (документов)

Если вы системный администратор и у вас есть локальная сеть с целой кучей пользователей, то наверняка есть сервер или какое другое устройство выполняющее функции сетевой папки для обмена файлами между пользователями. Основная проблема этих папок, что пользователи забывают удалять файлы и папка со временем разрастается и её объемы её начинают удивлять. Ниже я приведу небольшой скрипт решающий эти проблемы.

Для работы скрипта должна быть установлена 7-zip. В принципе для тех кто не хочет устанавливать ради этого программу, должно хватить только файла 7z.exe.

:: Autor: XaXaTyXa
:: Web: https://xaxatyxa.ru
:: date: 2012.01.11
::
:: Скрипт очистки заданного каталога,
:: с предварительной копией
:: в резервное место
:: Дополнительно удаление старых копий
::
:: Путь к 7z.exe
set prog_7zip="c:\progra~1\7-zip\7z.exe"
:: Путь к очищаемому каталогу
set clean_temp="c:\test\temp"
:: Путь к резервной копии удаляемого каталога
set backup_temp="c:\test\backup"
:: Информационный файл
set info_file="README.txt"
:: Сколько дней хранить бекапы временных файлов
set max_day=30
::
:: Архивируем бекапы и складываем в папку
%prog_7zip% a -t7z %backup_temp%\%date%.7z %clean_temp% -r
::
:: Удаляем содержимое очищаемого каталога
pushd %clean_temp%
rmdir /s /q %clean_temp%
popd
:: Формируем информационный файл
echo АХТУНГ !!! >%clean_temp%\%info_file%
echo Папка для временных документов была очищена %date% >>%clean_temp%\%info_file%
echo ------------------------------------------- >>%clean_temp%\%info_file%
echo ВНИМАНИЕ !!! >>%clean_temp%\%info_file%
echo Данная папка ТОЛЬКО для обмена информацией. >>%clean_temp%\%info_file%
echo Хранить в ней служебную информацию Ай как нехорошо ! >>%clean_temp%\%info_file%
echo и восстанавливается за тортики и кофиек >>%clean_temp%\%info_file%
:: Удаляем старые бекапы
FORFILES /P %backup_temp% /D -%max_day% /M *.* /C "cmd /c del @path"

[download id=»120″]